! CCL script for PPP connection to prairiedog.math.arizona.edu.
! Version: June 2003
!
! This script is not for ANSWER or HANGUP.
@ANSWER
@HANGUP
EXIT 0
!
! It is in fact for ORIGINATE.
@ORIGINATE
!
CHRDELAY 1
NOTE "Waiting for UAcats prompt..." 3
MATCHCLR
MATCHSTR 1 11 "00"
! Wait two seconds to get that prompt
MATCHREAD 20
! Send a carriage return and wait 5 seconds.
WRITE "\13"
MATCHREAD 50
NOTE "No UAcats prompt." 3
JUMP 99
!
@LABEL 11
PAUSE 10
WRITE "telnet prairiedog.math.arizona.edu\13"
NOTE "Waiting for prairiedog username prompt..." 3
MATCHCLR
MATCHSTR 1 12 "ogin"
MATCHREAD 50
NOTE "No prairiedog login prompt." 3
JUMP 99
!
@LABEL 12
PAUSE 10
WRITE "^u\13"
NOTE "Waiting for prairiedog password prompt..." 3
MATCHCLR
MATCHSTR 1 13 "assword"
MATCHREAD 50
NOTE "No prairiedog password prompt." 3
JUMP 99
!
@LABEL 13
PAUSE 10
WRITE "^p\13"
NOTE "Waiting for prairiedog command prompt..." 3
MATCHCLR
MATCHSTR 1 14 "$"
MATCHREAD 50
NOTE "No prairiedog command prompt." 3
JUMP 99
!
@LABEL 14
PAUSE 10
NOTE "Starting SLiRP..." 3
WRITE "exec slirplogin  -P\13"
PAUSE 10
EXIT 0
!
@LABEL 99
PAUSE 10
EXIT -6002 "Connection script failed."